Fornax.Seo 1.1.1

Fornax.Seo

A SEO meta tag generator for Fornax

Goals

• enhance the search engine visibility of Fornax-generated websites with:

  • structured data in JSON-LD format
  • OpenGraph <meta> tags
  • personalized social media links

• try to enforce some SEO best practises, e.g. requiring absolute URLs to all content items

Usage example

NOTE

The following requires fornax 0.14.0 or newer. Visit the wiki to learn how to use this package with earlier fornax versions.

• Change into a project directory and scaffold a new website

  fornax new
  

IMPORTANT

• Provide the root domain of your website:

  // loaders/globalloader.fsx
  #r "../_lib/Fornax.Core.dll"
  
  type SiteInfo = {
      title: string
      /// The root domain of your website - must be an absolute URL
      baseUrl: string
      description: string
  }
  

• Add personal authorship details, e.g.:

  // loaders/globalloader.fsx
  #r "nuget: Fornax.Seo"
  
  open Fornax.Seo
  
  let loader (projectRoot: string) (siteContent: SiteContents) =
      let siteInfo =
          { title = "Sample Fornax blog"
            baseUrl = "http://example.com"
            description = "Just a simple blog" }
  
      let onTheWeb =
          [ "linkedin.com/in/username"
            "github.com/username"
            "bitbucket.org/username"
            "facebook.com/username" ]
  
      let siteAuthor: ContentCreator =
          { Name = "Moi-même"
            Email = "info@example.com"
            SocialMedia = onTheWeb }
  
      siteContent.Add(siteInfo)
      siteContent.Add(siteAuthor)
  
      siteContent
  

Collect metadata from a content item (e.g., a blog posting)

// generators/post.fsx
#r "../_lib/Fornax.Core.dll"
#r "nuget: Fornax.Seo"
#load "layout.fsx"

open Html
open Fornax.Seo

let generate' (ctx: SiteContents) (page: string) =
    let siteInfo = ctx.TryGetValue<Globalloader.SiteInfo>()
    let siteName = siteInfo |> Option.map (fun si -> si.title)

    let tagline =
        siteInfo
        |> Option.map (fun si -> si.description)
        |> Option.defaultValue ""

    let siteAuthor =
        ctx.TryGetValue<ContentCreator>()
        |> Option.defaultValue ContentCreator.Default

    let siteRoot =
        siteInfo
        |> Option.map (fun si -> si.baseUrl)
        |> Option.defaultValue ContentObject.Default.BaseUrl

    let post =
        ctx.TryGetValues<Postloader.Post>()
        |> Option.defaultValue Seq.empty
        |> Seq.find (fun p -> p.file = page)

    let postMeta: ContentObject =
        { Title = post.title
          BaseUrl = siteRoot
          Url = post.file.Replace(System.IO.Path.GetExtension post.file, ".html")
          Description = tagline
          Author = { siteAuthor with Name = defaultArg post.author siteAuthor.Name }
          SiteName = siteName
          Headline = Some post.summary
          ObjectType = Some "Blog"
          ContentType = Some "BlogPosting"
          OpenGraphType = Some "article"
          Locale = Some "en-us"
          Published = post.published
          Modified = post.modified
          Tags = Some post.tags
          Meta =
              Some [ ("Image", defaultArg post.image $"{siteRoot}/images/avatar.jpg")
                     ("Publisher", defaultArg siteName siteAuthor.Name) ] }

    ctx.Add(postMeta)
    // . . .

Render SEO metadata in your page layout

// generators/layout.fsx
#r "../_lib/Fornax.Core.dll"
#r "nuget: Fornax.Seo"

open Html
open Fornax.Seo

// . . .

let layout (ctx: SiteContents) (active: string) (content: HtmlElement seq) =
    let siteAuthor =
        ctx.TryGetValue<ContentCreator>()
        |> Option.defaultValue ContentCreator.Default

    let seoData =
        ctx.TryGetValues<ContentObject>()
        |> Option.defaultValue Seq.empty

    let pageMeta =
        seoData
        |> Seq.tryFind (fun p -> p.Title.Contains(active))
        |> function
        | Some info -> info
        | _ -> { ContentObject.Default with Author = siteAuthor }

    html [] [
        head [] [
            meta [ CharSet "utf-8" ]
            meta [ Name "viewport"; Content "width=device-width, initial-scale=1" ]
            // . . .
            yield! seo pageMeta
        ]
        body [] [
            // . . .
            footer [] [ yield! socialMedia siteAuthor ]
        ]
    ]

    // . . .

Similar NuGet libraries (by framework)

.NET

• json-ld.net
• OpenGraph-Net

ASP.NET

• Winton.AspNetCore.Seo
• Definux.Seo

Umbraco

• Wavenet.Umbraco8.Seo

Contributing

A guide to building the project and making pull requests can be found here.

License

Distributed under the terms of the Mozilla Public License Version 2.0.